[xemacs-hg @ 2003-12-19 14:28:45 by youngs] 2003-12-15 Steve Youngs <sryoungs@bigpond.net.au> * wid-edit.el (lazy): New. (widget-child-value-get): New. (widget-child-value-inline): New. (widget-child-validate): New. (widget-type-value-create): New. (widget-type-default-get): New. (widget-type-match): New. This adds a "lazy" widget to allow the definition of recursive datatypes for customize. The composite widgets expand their subtypes immediately, which cause obvious problems for recursive datatypes. The "lazy" will only expand them when needed, hense the name. From Per Abrahamsen <abraham@dina.kvl.dk> 2003-12-15 Steve Youngs <sryoungs@bigpond.net.au> * lispref/customize.texi (Defining New Types): New node. From Per Abrahamsen <abraham@dina.kvl.dk>

#!/bin/sh
#
#	ad2c : Convert app-defaults file to C strings decls.
#
#	George Ferguson, ferguson@cs.rcohester.edu, 12 Nov 1990.
#	19 Mar 1991 : gf
#		Made it self-contained.
#	6 Jan 1992 : mycroft@gnu.ai.mit.edu (Charles Hannum)
#		Removed use of "-n" and ":read" label since Gnu and
#		IBM sed print pattern space on "n" command. Still works
#		with Sun sed, of course.
#	7 Jan 1992: matthew@sunpix.East.Sun.COM (Matthew Stier)
#		Escape quotes after escaping backslashes.
#
# Synched up with: Not in FSF.

sed '
/^!/d
/^$/d
s/\\/\\\\/g
s/\\$//g
s/"/\\"/g
s/^/"/
: test
/\\$/b slash
s/$/",/
p
d
: slash
n
/^!/d
/^$/d
s/"/\\"/g
s/\\\\/\\/g
s/\\n/\\\\n/g
s/\\t/\\\\t/g
s/\\f/\\\\f/g
s/\\b/\\\\b/g
b test' "$@"