case-tests.el: fix it on non-DEBUG_XEMACS; save standard-case-table, use it 2008-01-30 Aidan Kehoe <kehoea@parhasard.net> * automated/case-tests.el (pristine-case-table): New var, reflecting the standard case table before case-table.el messes with it. * automated/case-tests.el: Call Skip-Test-Unless correctly, following Vin's report of 20a807210801300635v7533d26rdb32a8d82fb4239b@mail.gmail.com . Use pristine-case-table, add in a couple more tests. * automated/test-harness.el (test-harness-from-buffer): Update the error message in the light of tests skipped for other reasons (not to do with absent packages). In this case, because we're exposing diagnostics in a DEBUG_XEMACS build that are no appropriate to expose to non-DEBUG_XEMACS builds.

#!/bin/sh
#
#	ad2c : Convert app-defaults file to C strings decls.
#
#	George Ferguson, ferguson@cs.rcohester.edu, 12 Nov 1990.
#	19 Mar 1991 : gf
#		Made it self-contained.
#	6 Jan 1992 : mycroft@gnu.ai.mit.edu (Charles Hannum)
#		Removed use of "-n" and ":read" label since Gnu and
#		IBM sed print pattern space on "n" command. Still works
#		with Sun sed, of course.
#	7 Jan 1992: matthew@sunpix.East.Sun.COM (Matthew Stier)
#		Escape quotes after escaping backslashes.
#
# Synched up with: Not in FSF.

sed '
/^!/d
/^$/d
s/\\/\\\\/g
s/\\$//g
s/"/\\"/g
s/^/"/
: test
/\\$/b slash
s/$/",/
p
d
: slash
n
/^!/d
/^$/d
s/"/\\"/g
s/\\\\/\\/g
s/\\n/\\\\n/g
s/\\t/\\\\t/g
s/\\f/\\\\f/g
s/\\b/\\\\b/g
b test' "$@"