Mercurial > hg > xemacs-beta

view lisp/gtk-ffi.el @ 5294:bbff29a01820

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Add compiler macros and compilation sanity-checks for functions with keywords. 2010-10-25 Aidan Kehoe <kehoea@parhasard.net> Add compiler macros and compilation sanity-checking for various functions that take keywords. * byte-optimize.el (side-effect-free-fns): #'symbol-value is side-effect free and not error free. * bytecomp.el (byte-compile-normal-call): Check keyword argument lists for sanity; store information about the positions where keyword arguments start using the new byte-compile-keyword-start property. * cl-macs.el (cl-const-expr-val): Take a new optional argument, cl-not-constant, defaulting to nil, in this function; return it if the expression is not constant. (cl-non-fixnum-number-p): Make this into a separate function, we want to pass it to #'every. (eql): Use it. (define-star-compiler-macros): Use the same code to generate the member*, assoc* and rassoc* compiler macros; special-case some code in #'add-to-list in subr.el. (remove, remq): Add compiler macros for these two functions, in preparation for #'remove being in C. (define-foo-if-compiler-macros): Transform (remove-if-not ...) calls to (remove ... :if-not) at compile time, which will be a real win once the latter is in C. (define-substitute-if-compiler-macros) (define-subst-if-compiler-macros): Similarly for these functions. (delete-duplicates): Change this compiler macro to use #'plists-equal; if we don't have information about the type of SEQUENCE at compile time, don't bother attempting to inline the call, the function will be in C soon enough. (equalp): Remove an old commented-out compiler macro for this, if we want to see it it's in version control. (subst-char-in-string): Transform this to a call to nsubstitute or nsubstitute, if that is appropriate. * cl.el (ldiff): Don't call setf here, this makes for a load-time dependency problem in cl-macs.el
author Aidan Kehoe <kehoea@parhasard.net>
date Mon, 25 Oct 2010 13:04:04 +0100
parents 0784d089fdc9
children 3889ef128488 308d34e9f07d
line wrap: on
line source

;;; gtk-ffi.el --- Foreign function interface for the GTK object system

;; Copyright (C) 2000 Free Software Foundation

;; Maintainer: William Perry <wmperry@gnu.org>
;; Keywords: extensions, dumped

;; This file is part of XEmacs.

;; XEmacs is free software; you can redistribute it and/or modify it
;; under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; XEmacs is distributed in the hope that it will be useful, but
;; WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;; General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with XEmacs; see the file COPYING.  If not, write to the Free
;; Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
;; 02111-1307, USA.

;;; Synched up with: Not in FSF

;;; Commentary:

;; This file is dumped with XEmacs.

(defvar gtk-type-aliases '((GtkType . guint)
			   (GdkAtom . gulong)
			   (GdkBitmap . GdkWindow)
			   (time_t    . guint)
			   (none      . void)
			   (GdkDrawable . GdkWindow)
			   (GdkBitmap . GdkWindow)
			   (GdkPixmap . GdkWindow))
  "An assoc list of aliases for commonly used GTK types that are not
really part of the object system.")

(defvar gtk-ffi-debug nil
  "If non-nil, all functions defined wiht `gtk-import-function' will be checked
for missing marshallers.")

(defun gtk-ffi-check-function (func)
  ;; We don't call gtk-main or gtk-main-quit because it thoroughly
  ;; hoses us (locks up xemacs handling events, but no lisp).
  (if (not (memq func '(gtk-main gtk-main-quit)))
      (condition-case err
	  (funcall func)
	(error
	 (case (car err)
	   (wrong-number-of-arguments nil)
	   (error
	    (if (string= "Could not locate marshaller function" (nth 1 err))
		(progn
		  (set-buffer (get-buffer-create "needed marshallers"))
		  (display-buffer (current-buffer))
		  (goto-char (point-max))
		  (insert
		   (format "%S\n"
			   (split-string
			    (substring (nth 2 err) (length "emacs_gtk_marshal_")) "_+")))))))))))

(defmacro gtk-import-function (retval name &rest args)
  (if (symbolp name)
      (setq name (symbol-name name)))
  (let ((lisp-name (intern (replace-in-string name "_" "-")))
	(doc-string nil))
    (setq retval (or (cdr-safe (assoc retval gtk-type-aliases)) retval)
	  doc-string (concat "The lisp version of " name ".\n"
			     (if args
				 (concat "Prototype: " (prin1-to-string args)))))

    ;; Drop off any naming of arguments, etc.
    (if (and args (consp (car args)))
	(setq args (mapcar 'car args)))

    ;; Get rid of any type aliases.
    (setq args (mapcar (lambda (x)
			 (or (cdr-safe (assoc x gtk-type-aliases)) x)) args))

    `(progn
       (defun ,lisp-name (&rest args)
	 ,doc-string
	 (if (not (get (quote ,lisp-name) 'gtk-ffi nil))
	     (put (quote ,lisp-name) 'gtk-ffi
		  (gtk-import-function-internal (quote ,retval) ,name
						(quote ,args))))
	 (gtk-call-function (get (quote ,lisp-name) 'gtk-ffi 'ignore) args))
       (and gtk-ffi-debug (gtk-ffi-check-function (quote ,lisp-name))))))

(defmacro gtk-import-variable (type name)
  (if (symbolp name) (setq name (symbol-name name)))
  (let ((lisp-name (intern (replace-in-string name "_" "-")))
	(doc-string nil))
    (setq type (or (cdr-safe (assoc type gtk-type-aliases)) type)
	  doc-string (concat "Retrieve the variable " name " (type: " (symbol-name type) ").\n"))
    `(defun ,lisp-name ()
       ,doc-string
       (gtk-import-variable-internal (quote ,type) ,name))))

(provide 'gtk-ffi)