[xemacs-hg @ 2003-04-24 05:33:43 by youngs] 2003-04-24 Matthew O. Persico <persicom@acedsl.com> * unicode.c: Removed trailing commas in some enums; older (Solaris 2.7 cc) compiler produced volumous warnings. * text.c: Replaced char initialization of static Ibyte strcasecmp_charmap[] with octal numeric init. Apparently older (Solaris 2.7 cc) compiler treats quoted octals as signed, causing 256 signed-assigned-to-unsigned warnings. * lrecord.h: Removed trailing commas in some enums; older (Solaris 2.7 cc) compiler produced volumous warnings. * lisp.h: Removed trailing commas in some enums; older (Solaris 2.7 cc) compiler produced volumous warnings. * frame.c: Removed trailing commas in some enums; older (Solaris 2.7 cc) compiler produced volumous warnings. * file-coding.h: Removed trailing commas in some enums; older (Solaris 2.7 cc) compiler produced volumous warnings.

#!/bin/sh
#
#	ad2c : Convert app-defaults file to C strings decls.
#
#	George Ferguson, ferguson@cs.rcohester.edu, 12 Nov 1990.
#	19 Mar 1991 : gf
#		Made it self-contained.
#	6 Jan 1992 : mycroft@gnu.ai.mit.edu (Charles Hannum)
#		Removed use of "-n" and ":read" label since Gnu and
#		IBM sed print pattern space on "n" command. Still works
#		with Sun sed, of course.
#	7 Jan 1992: matthew@sunpix.East.Sun.COM (Matthew Stier)
#		Escape quotes after escaping backslashes.
#
# Synched up with: Not in FSF.

sed '
/^!/d
/^$/d
s/\\/\\\\/g
s/\\$//g
s/"/\\"/g
s/^/"/
: test
/\\$/b slash
s/$/",/
p
d
: slash
n
/^!/d
/^$/d
s/"/\\"/g
s/\\\\/\\/g
s/\\n/\\\\n/g
s/\\t/\\\\t/g
s/\\f/\\\\f/g
s/\\b/\\\\b/g
b test' "$@"