Mercurial > hg > xemacs-beta

view lisp/gtk-file-dialog.el @ 4885:6772ce4d982b

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Fix hash tables, #'member*, #'assoc*, #'eql compiler macros if bignums lisp/ChangeLog addition: 2010-01-24 Aidan Kehoe <kehoea@parhasard.net> Correct the semantics of #'member*, #'eql, #'assoc* in the presence of bignums; change the integerp byte code to fixnump semantics. * bytecomp.el (fixnump, integerp, byte-compile-integerp): Change the integerp byte code to fixnump; add a byte-compile method to integerp using fixnump and numberp and avoiding a funcall most of the time, since in the non-core contexts where integerp is used, it's mostly distinguishing between fixnums and things that are not numbers at all. * byte-optimize.el (side-effect-free-fns, byte-after-unbind-ops) (byte-compile-side-effect-and-error-free-ops): Replace the integerp bytecode with fixnump; add fixnump to the side-effect-free-fns. Add the other extended number type predicates to the list in passing. * obsolete.el (floatp-safe): Mark this as obsolete. * cl.el (eql): Go into more detail in the docstring here. Don't bother checking whether both arguments are numbers; one is enough, #'equal will fail correctly if they have distinct types. (subst): Replace a call to #'integerp (deciding whether to use #'memq or not) with one to #'fixnump. Delete most-positive-fixnum, most-negative-fixnum from this file; they're now always in C, so they can't be modified from Lisp. * cl-seq.el (member*, assoc*, rassoc*): Correct these functions in the presence of bignums. * cl-macs.el (cl-make-type-test): The type test for a fixnum is now fixnump. Ditch floatp-safe, use floatp instead. (eql): Correct this compiler macro in the presence of bignums. (assoc*): Correct this compiler macro in the presence of bignums. * simple.el (undo): Change #'integerp to #'fixnump here, since we use #'delq with the same value as ELT a few lines down. src/ChangeLog addition: 2010-01-24 Aidan Kehoe <kehoea@parhasard.net> Fix problems with #'eql, extended number types, and the hash table implementation; change the Bintegerp bytecode to fixnump semantics even on bignum builds, since #'integerp can have a fast implementation in terms of #'fixnump for most of its extant uses, but not vice-versa. * lisp.h: Always #include number.h; we want the macros provided in it, even if the various number types are not available. * number.h (NON_FIXNUM_NUMBER_P): New macro, giving 1 when its argument is of non-immediate number type. Equivalent to FLOATP if WITH_NUMBER_TYPES is not defined. * elhash.c (lisp_object_eql_equal, lisp_object_eql_hash): Use NON_FIXNUM_NUMBER_P in these functions, instead of FLOATP, giving more correct behaviour in the presence of the extended number types. * bytecode.c (Bfixnump, execute_optimized_program): Rename Bintegerp to Bfixnump; change its semantics to reflect the new name on builds with bignum support. * data.c (Ffixnump, Fintegerp, syms_of_data, vars_of_data): Always make #'fixnump available, even on non-BIGNUM builds; always implement #'integerp in this file, even on BIGNUM builds. Move most-positive-fixnum, most-negative-fixnum here from number.c, so they are Lisp constants even on builds without number types, and attempts to change or bind them error. Use the NUMBERP and INTEGERP macros even on builds without extended number types. * data.c (fixnum_char_or_marker_to_int): Rename this function from integer_char_or_marker_to_int, to better reflect the arguments it accepts. * number.c (Fevenp, Foddp, syms_of_number): Never provide #'integerp in this file. Remove #'oddp, #'evenp; their implementations are overridden by those in cl.el. * number.c (vars_of_number): most-positive-fixnum, most-negative-fixnum are no longer here. man/ChangeLog addition: 2010-01-23 Aidan Kehoe <kehoea@parhasard.net> Generally: be careful to say fixnum, not integer, when talking about fixed-precision integral types. I'm sure I've missed instances, both here and in the docstrings, but this is a decent start. * lispref/text.texi (Columns): Document where only fixnums, not integers generally, are accepted. (Registers): Remove some ancient char-int confoundance here. * lispref/strings.texi (Creating Strings, Creating Strings): Be more exact in describing where fixnums but not integers in general are accepted. (Creating Strings): Use a more contemporary example to illustrate how concat deals with lists including integers about #xFF. Delete some obsolete documentation on same. (Char Table Types): Document that only fixnums are accepted as values in syntax tables. * lispref/searching.texi (String Search, Search and Replace): Be exact in describing where fixnums but not integers in general are accepted. * lispref/range-tables.texi (Range Tables): Be exact in describing them; only fixnums are accepted to describe ranges. * lispref/os.texi (Killing XEmacs, User Identification) (Time of Day, Time Conversion): Be more exact about using fixnum where only fixed-precision integers are accepted. * lispref/objects.texi (Integer Type): Be more exact (and up-to-date) about the possible values for integers. Cross-reference to documentation of the bignum extension. (Equality Predicates): (Range Table Type): (Array Type): Use fixnum, not integer, to describe a fixed-precision integer. (Syntax Table Type): Correct some English syntax here. * lispref/numbers.texi (Numbers): Change the phrasing here to use fixnum to mean the fixed-precision integers normal in emacs. Document that our terminology deviates from that of Common Lisp, and that we're working on it. (Compatibility Issues): Reiterate the Common Lisp versus Emacs Lisp compatibility issues. (Comparison of Numbers, Arithmetic Operations): * lispref/commands.texi (Command Loop Info, Working With Events): * lispref/buffers.texi (Modification Time): Be more exact in describing where fixnums but not integers in general are accepted.
author Aidan Kehoe <kehoea@parhasard.net>
date Sun, 24 Jan 2010 15:21:27 +0000
parents 7039e6323819
children 308d34e9f07d
line wrap: on
line source

;;; gtk-file-dialog.el --- A nicer file selection dialog for XEmacs w/GTK primitives

;; Copyright (C) 2000 Free Software Foundation, Inc.

;; Maintainer: William M. Perry <wmperry@gnu.org>
;; Keywords: extensions, internal

;; This file is part of XEmacs.

;; XEmacs is free software; you can redistribute it and/or modify it
;; under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; XEmacs is distributed in the hope that it will be useful, but
;; WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;; General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with XEmacs; see the file COPYING.  If not, write to the 
;; Free Software Foundation, 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Synched up with: Not in FSF.

;;; Commentary:

;; The default GTK file selection dialog is not sufficient for our
;; needs.  Limitations include:
;;
;; - not derived from GtkDialog
;; - no support for filters based on file types
;; - no support for setting an initial directory
;; - no way to tell it 'file must exist'
;; - no easy way to tell it to look at directories only
;; - ugly as sin
;;
;; This attempts to rectify the situation.

(globally-declare-fboundp
 '(gtk-clist-clear
   gtk-clist-freeze gtk-clist-append
   gtk-clist-thaw gtk-combo-set-popdown-strings gtk-dialog-new
   gtk-dialog-vbox gtk-dialog-action-area gtk-window-set-title
   gtk-button-new-with-label gtk-container-add gtk-signal-connect
   gtk-entry-get-text gtk-widget-destroy gtk-combo-new
   gtk-combo-disable-activate gtk-box-pack-start gtk-combo-entry
   gtk-hbox-new gtk-clist-new-with-titles gtk-scrolled-window-new
   gtk-widget-set-usize gtk-clist-get-text gtk-entry-set-text
   gtk-button-clicked gtk-option-menu-new gtk-menu-new
   gtk-label-new gtk-menu-item-new-with-label gtk-menu-append
   gtk-widget-show gtk-option-menu-set-menu gtk-box-pack-end
   gtk-entry-new gtk-widget-set-sensitive gtk-widget-realize))

(defun gtk-file-dialog-fill-file-list (dialog dir)
  (if (not dir)
      (setq dir (get dialog 'x-file-dialog-current-dir nil)))

  (put dialog 'x-file-dialog-current-dir dir)

  (let ((list (get dialog 'x-file-dialog-files-list nil))
	;(remotep (file-remote-p dir))
	)
    (if (not list)
	nil
      (gtk-clist-clear list)
      (gtk-clist-freeze list)
      ;; NOTE: Current versions of efs / ange-ftp do not honor the
      ;; files-only flag to directory-files, but actually DOING these
      ;; checks is hideously expensive.  Leave it turned off for now.
      (mapc #'(lambda (f)
		(if (or t		; Lets just wait for EFS to
			;(not remotep)	; fix itself, shall we?
			;(not (file-directory-p (expand-file-name f dir)))
			)
		    (gtk-clist-append list (list f))))
	    (directory-files dir nil
			     (get dialog 'x-file-dialog-active-filter nil)
			     nil t))
      (gtk-clist-thaw list))))

(defun gtk-file-dialog-fill-directory-list (dialog dir)
  (let ((subdirs (directory-files dir nil nil nil 5))
	;(remotep (file-remote-p dir))
	;(selected-dir (get dialog 'x-file-dialog-current-dir "/"))
	(directory-list (get dialog 'x-file-dialog-directory-list)))

    (gtk-clist-freeze directory-list)
    (gtk-clist-clear directory-list)

    (while subdirs
      (if (equal "." (car subdirs))
	  nil
	;; NOTE: Current versions of efs / ange-ftp do not honor the
	;; files-only flag to directory-files, but actually DOING these
	;; checks is hideously expensive.  Leave it turned off for now.
	(if (or t			; Lets just wait for EFS to
		;(not remotep)		; fix itself, shall we?
		;(file-directory-p (expand-file-name (car subdirs) dir))
		)
	    (gtk-clist-append directory-list (list (car subdirs)))))
      (pop subdirs))
    (gtk-clist-thaw directory-list)))

(defun gtk-file-dialog-update-dropdown (dialog dir)
  (let ((combo-box (get dialog 'x-file-dialog-select-list))
	(components (reverse
		     (delete ""
			     (split-string dir
					   (concat "[" (char-to-string directory-sep-char) "]")))))
	(entries nil))

    (while components
      (push (concat "/" (mapconcat 'identity (reverse components)
				   (char-to-string directory-sep-char)))
	    entries)
      (pop components))
    (push (expand-file-name "." "~/") entries)
    (gtk-combo-set-popdown-strings combo-box (nreverse entries))))

(defun gtk-file-dialog-select-directory (dialog dir)
  (gtk-file-dialog-fill-directory-list dialog dir)
  (gtk-file-dialog-fill-file-list dialog dir)
  (gtk-file-dialog-update-dropdown dialog dir))

(defun gtk-file-dialog-new (&rest keywords)
  "Create a XEmacs file selection dialog.
Optional keyword arguments allowed:

:title			The title of the dialog
:initial-directory	Initial directory to show
:filter-list		List of filter descriptions and filters
:file-must-exist	Whether the file must exist or not
:directory		Look for a directory instead
:callback		Function to call with one arg, the selection
"
  (let* ((dialog (gtk-dialog-new))
	 (vbox (gtk-dialog-vbox dialog))
	 (dir (plist-get keywords :initial-directory default-directory))
	 (button-area (gtk-dialog-action-area dialog))
	 ;(initializing-gtk-file-dialog t)
	 (select-box nil)
	 button hbox)

    (put dialog 'type 'dialog)

    (gtk-window-set-title dialog (plist-get keywords :title "Select a file..."))

    (setq button (gtk-button-new-with-label "OK"))
    (gtk-container-add button-area button)
    (gtk-signal-connect button 'clicked
			(lambda (button dialog)
			  (funcall
			   (get dialog 'x-file-dialog-callback 'ignore)
			   (gtk-entry-get-text
			    (get dialog 'x-file-dialog-entry nil)))
			  (gtk-widget-destroy dialog))
			dialog)
    (put dialog 'x-file-dialog-ok-button button)

    (setq button (gtk-button-new-with-label "Cancel"))
    (gtk-container-add button-area button)
    (gtk-signal-connect button 'clicked
			(lambda (button dialog)
			  (gtk-widget-destroy dialog)) dialog)

    (put dialog 'x-file-dialog-cancel-button button)
    (put dialog 'x-file-dialog-callback (plist-get keywords :callback 'ignore))
    (put dialog 'x-file-dialog-construct-args keywords)
    (put dialog 'x-file-dialog-current-dir dir)

    ;; Dropdown list of directories...
    (setq select-box (gtk-combo-new))
    (gtk-combo-disable-activate select-box)
    (gtk-box-pack-start vbox select-box nil nil 5)
    (put dialog 'x-file-dialog-select-list select-box)

    ;; Hitting return in the entry will change dirs...
    (gtk-signal-connect (gtk-combo-entry select-box) 'activate
			(lambda (entry dialog)
			  (gtk-file-dialog-select-directory dialog
							    (gtk-entry-get-text entry)))
			dialog)

    ;; Start laying out horizontally...
    (setq hbox (gtk-hbox-new nil 0))
    (gtk-box-pack-start vbox hbox t t 5)

    ;; Directory listing
    (let ((directories (gtk-clist-new-with-titles 1 '("Directories")))
	  (scrolled (gtk-scrolled-window-new nil nil)))
      (gtk-container-add scrolled directories)
      (gtk-widget-set-usize scrolled 200 300)
      (gtk-box-pack-start hbox scrolled t t 0)
      (put dialog 'x-file-dialog-directory-list directories)
      (put dialog 'x-file-dialog-directory-scrolled scrolled)

      (gtk-signal-connect directories 'select-row
			  (lambda (list row column event dialog)
			    (let ((dir (expand-file-name
					 (gtk-clist-get-text
					  (get dialog 'x-file-dialog-directory-list)
					  row column)
					 (get dialog 'x-file-dialog-current-dir))))
			      (if (and (misc-user-event-p event)
				       (event-function event))
				  (gtk-file-dialog-select-directory dialog dir)
				(gtk-entry-set-text
				 (get dialog 'x-file-dialog-entry)
				 dir))))
			  dialog)
      )

    (if (plist-get keywords :directory nil)
	;; Directory listings only do not need the file or filters buttons.
	nil
      ;; File listing
      (let ((list (gtk-clist-new-with-titles 1 '("Files")))
	    (scrolled (gtk-scrolled-window-new nil nil)))
	(gtk-container-add scrolled list)
	(gtk-widget-set-usize scrolled 200 300)
	(gtk-box-pack-start hbox scrolled t t 0)

	(gtk-signal-connect list 'select-row
			    (lambda (list row column event dialog)
			      (gtk-entry-set-text
			       (get dialog 'x-file-dialog-entry nil)
			       (expand-file-name
				(gtk-clist-get-text list row column)
				(get dialog 'x-file-dialog-current-dir nil)))
			      (if (and (misc-user-event-p event)
				       (event-function event))
				  ;; Got a double or triple click event...
				  (gtk-button-clicked
				   (get dialog 'x-file-dialog-ok-button nil))))
			    dialog)

	(put dialog 'x-file-dialog-files-list list))

      ;; Filters
      (if (not (plist-get keywords :filter-list nil))
	  ;; Don't need to bother packing this
	  nil
	(setq hbox (gtk-hbox-new nil 0))
	(gtk-box-pack-start vbox hbox nil nil 0)

	(let ((label nil)
	      (options (plist-get keywords :filter-list nil))
	      (omenu nil)
	      (menu nil)
	      (item nil))
	  (setq omenu (gtk-option-menu-new)
		menu (gtk-menu-new)
		label (gtk-label-new "Filter: "))

	  (put dialog 'x-file-dialog-active-filter (cdr (car options)))
	  (mapc (lambda (o)
		  (setq item (gtk-menu-item-new-with-label (car o)))
		  (gtk-signal-connect item 'activate
				      (lambda (obj data)
					(put (car data) 'x-file-dialog-active-filter (cdr data))
					(gtk-file-dialog-fill-file-list (car data) nil))
				      (cons dialog (cdr o)))
		  (gtk-menu-append menu item)
		  (gtk-widget-show item)) options)
	  (gtk-option-menu-set-menu omenu menu)
	  (gtk-box-pack-end hbox omenu nil nil 0)
	  (gtk-box-pack-end hbox label nil nil 0))))

      ;; Entry
    (let ((entry (gtk-entry-new)))
      (if (plist-get keywords :directory nil)
	  nil
	(gtk-box-pack-start vbox entry nil nil 0))
      (if (plist-get keywords :file-must-exist nil)
	  (progn
	    (gtk-widget-set-sensitive (get dialog 'x-file-dialog-ok-button nil) nil)
	    (gtk-signal-connect entry 'changed
				(lambda (entry dialog)
				  (gtk-widget-set-sensitive
				   (get dialog 'x-file-dialog-ok-button)
				   (file-exists-p (gtk-entry-get-text entry))))
				dialog)))
      (put dialog 'x-file-dialog-entry entry))

    (gtk-widget-realize dialog)


    ;; Populate the file list if necessary
    (gtk-file-dialog-select-directory dialog dir)
    dialog))

(provide 'gtk-file-dialog)