[xemacs-hg @ 2002-07-06 18:56:24 by adrian] [R21.4] [PATCH] xemacs-21.5: Fix improper use of indef. art. "a" -------------------- ChangeLog entries follow: -------------------- man/ChangeLog addition: 2002-07-06 Adrian Aichner <adrian@xemacs.org> * new-users-guide/custom1.texi (Customizing key Bindings): Fix improper use of indef. art. "a". 2002-07-06 Adrian Aichner <adrian@xemacs.org> * lispref/commands.texi (Peeking and Discarding): Ditto. * lispref/customize.texi (Type Keywords): Ditto. * lispref/dragndrop.texi (Drop Interface): Ditto. 2002-07-06 Adrian Aichner <adrian@xemacs.org> * termcap.texi (Clearing): Ditto. * widget.texi (User Interface): Ditto. * widget.texi (Basic Types): Ditto. * widget.texi (group): Ditto.

#!/bin/sh
#
#	ad2c : Convert app-defaults file to C strings decls.
#
#	George Ferguson, ferguson@cs.rcohester.edu, 12 Nov 1990.
#	19 Mar 1991 : gf
#		Made it self-contained.
#	6 Jan 1992 : mycroft@gnu.ai.mit.edu (Charles Hannum)
#		Removed use of "-n" and ":read" label since Gnu and
#		IBM sed print pattern space on "n" command. Still works
#		with Sun sed, of course.
#	7 Jan 1992: matthew@sunpix.East.Sun.COM (Matthew Stier)
#		Escape quotes after escaping backslashes.
#
# Synched up with: Not in FSF.

sed '
/^!/d
/^$/d
s/\\/\\\\/g
s/\\$//g
s/"/\\"/g
s/^/"/
: test
/\\$/b slash
s/$/",/
p
d
: slash
n
/^!/d
/^$/d
s/"/\\"/g
s/\\\\/\\/g
s/\\n/\\\\n/g
s/\\t/\\\\t/g
s/\\f/\\\\f/g
s/\\b/\\\\b/g
b test' "$@"