Mercurial > hg > xemacs-beta

view lisp/code-init.el @ 853:2b6fa2618f76

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
[xemacs-hg @ 2002-05-28 08:44:22 by ben] merge my stderr-proc ws make-docfile.c: Fix places where we forget to check for EOF. code-init.el: Don't use CRLF conversion by default on process output. CMD.EXE and friends work both ways but Cygwin programs don't like the CRs. code-process.el, multicast.el, process.el: Removed. Improvements to call-process-internal: -- allows a buffer to be specified for input and stderr output -- use it on all systems -- implement C-g as documented -- clean up and comment call-process-region uses new call-process facilities; no temp file. remove duplicate funs in process.el. comment exactly how coding systems work and fix various problems. open-multicast-group now does similar coding-system frobbing to open-network-stream. dumped-lisp.el, faces.el, msw-faces.el: Fix some hidden errors due to code not being defined at the right time. xemacs.mak: Add -DSTRICT. ================================================================ ALLOW SEPARATION OF STDOUT AND STDERR IN PROCESSES ================================================================ Standard output and standard error can be processed separately in a process. Each can have its own buffer, its own mark in that buffer, and its filter function. You can specify a separate buffer for stderr in `start-process' to get things started, or use the new primitives: set-process-stderr-buffer process-stderr-buffer process-stderr-mark set-process-stderr-filter process-stderr-filter Also, process-send-region takes a 4th optional arg, a buffer. Currently always uses a pipe() under Unix to read the error output. (#### Would a PTY be better?) sysdep.h, sysproc.h, unexfreebsd.c, unexsunos4.c, nt.c, emacs.c, callproc.c, symsinit.h, sysdep.c, Makefile.in.in, process-unix.c: Delete callproc.c. Move child_setup() to process-unix.c. wait_for_termination() now only needed on a few really old systems. console-msw.h, event-Xt.c, event-msw.c, event-stream.c, event-tty.c, event-unixoid.c, events.h, process-nt.c, process-unix.c, process.c, process.h, procimpl.h: Rewrite the process methods to handle a separate channel for error input. Create Lstreams for reading in the error channel. Many process methods need change. In general the changes are fairly clear as they involve duplicating what's used for reading the normal stdout and changing for stderr -- although tedious, as such changes are required throughout the entire process code. Rewrote the code that reads process output to do two loops, one for stdout and one for stderr. gpmevent.c, tooltalk.c: set_process_filter takes an argument for stderr. ================================================================ NEW ERROR-TRAPPING MECHANISM ================================================================ Totally rewrite error trapping code to be unified and support more features. Basic function is call_trapping_problems(), which lets you specify, by means of flags, what sorts of problems you want trapped. these can include -- quit -- errors -- throws past the function -- creation of "display objects" (e.g. buffers) -- deletion of already-existing "display objects" (e.g. buffers) -- modification of already-existing buffers -- entering the debugger -- gc -- errors->warnings (ala suspended errors) etc. All other error funs rewritten in terms of this one. Various older mechanisms removed or rewritten. window.c, insdel.c, console.c, buffer.c, device.c, frame.c: When creating a display object, added call to note_object_created(), for use with trapping_problems mechanism. When deleting, call check_allowed_operation() and note_object deleted(). The trapping-problems code records the objects created since the call-trapping-problems began. Those objects can be deleted, but none others (i.e. previously existing ones). bytecode.c, cmdloop.c: internal_catch takes another arg. eval.c: Add long comments describing the "five lists" used to maintain state (backtrace, gcpro, specbind, etc.) in the Lisp engine. backtrace.h, eval.c: Implement trapping-problems mechanism, eliminate old mechanisms or redo in terms of new one. frame.c, gutter.c: Flush out the concept of "critical display section", defined by the in_display() var. Use an internal_bind() to get it reset, rather than just doing it at end, because there may be a non-local exit. event-msw.c, event-stream.c, console-msw.h, device.c, dialog-msw.c, frame.c, frame.h, intl.c, toolbar.c, menubar-msw.c, redisplay.c, alloc.c, menubar-x.c: Make use of new trapping-errors stuff and rewrite code based on old mechanisms. glyphs-widget.c, redisplay.h: Protect calling Lisp in redisplay. insdel.c: Protect hooks against deleting existing buffers. frame-msw.c: Use EQ, not EQUAL in hash tables whose keys are just numbers. Otherwise we run into stickiness in redisplay because internal_equal() can QUIT. ================================================================ SIGNAL, C-G CHANGES ================================================================ Here we change the way that C-g interacts with event reading. The idea is that a C-g occurring while we're reading a user event should be read as C-g, but elsewhere should be a QUIT. The former code did all sorts of bizarreness -- requiring that no QUIT occurs anywhere in event-reading code (impossible to enforce given the stuff called or Lisp code invoked), and having some weird system involving enqueue/dequeue of a C-g and interaction with Vquit_flag -- and it didn't work. Now, we simply enclose all code where we want C-g read as an event with {begin/end}_dont_check_for_quit(). This completely turns off the mechanism that checks (and may remove or alter) C-g in the read-ahead queues, so we just get the C-g normal. Signal.c documents this very carefully. cmdloop.c: Correct use of dont_check_for_quit to new scheme, remove old out-of-date comments. event-stream.c: Fix C-g handling to actually work. device-x.c: Disable quit checking when err out. signal.c: Cleanup. Add large descriptive comment. process-unix.c, process-nt.c, sysdep.c: Use QUIT instead of REALLY_QUIT. It's not necessary to use REALLY_QUIT and just confuses the issue. lisp.h: Comment quit handlers. ================================================================ CONS CHANGES ================================================================ free_cons() now takes a Lisp_Object not the result of XCONS(). car and cdr have been renamed so that they don't get used directly; go through XCAR(), XCDR() instead. alloc.c, dired.c, editfns.c, emodules.c, fns.c, glyphs-msw.c, glyphs-x.c, glyphs.c, keymap.c, minibuf.c, search.c, eval.c, lread.c, lisp.h: Correct free_cons calling convention: now takes Lisp_Object, not Lisp_Cons chartab.c: Eliminate direct use of ->car, ->cdr, should be black box. callint.c: Rewrote using EXTERNAL_LIST_LOOP to avoid use of Lisp_Cons. ================================================================ USE INTERNAL-BIND-* ================================================================ eval.c: Cleanups of these funs. alloc.c, fileio.c, undo.c, specifier.c, text.c, profile.c, lread.c, redisplay.c, menubar-x.c, macros.c: Rewrote to use internal_bind_int() and internal_bind_lisp_object() in place of whatever varied and cumbersome mechanisms were formerly there. ================================================================ SPECBIND SANITY ================================================================ backtrace.h: - Improved comments backtrace.h, bytecode.c, eval.c: Add new mechanism check_specbind_stack_sanity() for sanity checking code each time the catchlist or specbind stack change. Removed older prototype of same mechanism. ================================================================ MISC ================================================================ lisp.h, insdel.c, window.c, device.c, console.c, buffer.c: Fleshed out authorship. device-msw.c: Correct bad Unicode-ization. print.c: Be more careful when not initialized or in fatal error handling. search.c: Eliminate running_asynch_code, an FSF holdover. alloc.c: Added comments about gc-cons-threshold. dialog-x.c: Use begin_gc_forbidden() around code to build up a widget value tree, like in menubar-x.c. gui.c: Use Qunbound not Qnil as the default for gethash. lisp-disunion.h, lisp-union.h: Added warnings on use of VOID_TO_LISP(). lisp.h: Use ERROR_CHECK_STRUCTURES to turn on ERROR_CHECK_TRAPPING_PROBLEMS and ERROR_CHECK_TYPECHECK lisp.h: Add assert_with_message. lisp.h: Add macros for gcproing entire arrays. (You could do this before but it required manual twiddling the gcpro structure.) lisp.h: Add prototypes for new functions defined elsewhere.
author ben
date Tue, 28 May 2002 08:45:36 +0000
parents 943eaba38521
children 7f62a956b825
line wrap: on
line source

;;; code-init.el --- Handle coding system default values

;; Copyright (C) 2001, 2002 Ben Wing.

;; This file is part of XEmacs.

;; XEmacs is free software; you can redistribute it and/or modify it
;; under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; XEmacs is distributed in the hope that it will be useful, but
;; WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;; General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with XEmacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; Placed in a separate file so it can be loaded after the various
;; coding systems have been created, because we'll be using them at
;; load time.

;;; Code:

(defcustom eol-detection-enabled-p (or (featurep 'mule)
				       (memq system-type '(windows-nt
							   cygwin32))
				       (featurep 'unix-default-eol-detection))
"True if XEmacs automatically detects the EOL type when reading files.
Normally, this is always the case on Windows or when international (Mule)
support is compiled into this XEmacs.  Otherwise, it is currently off by
default, but this may change.  Don't set this; nothing will happen.  Instead,
use the Options menu or `set-eol-detection'."
  :group 'encoding
  :type 'boolean
  ;; upon initialization, we don't want the whole business of
  ;; set-eol-detection to be called.  We will init everything appropriately
  ;; later in the same file, when reset-language-environment is called.
  :initialize #'(lambda (var val)
		  (setq eol-detection-enabled-p val))
  :set #'(lambda (var val)
	   (set-eol-detection val)
	   (setq eol-detection-enabled-p val)))

(defun set-eol-detection (flag)
  "Enable (if FLAG is non-nil) or disable automatic EOL detection of files.
EOL detection is enabled by default on Windows or when international (Mule)
support is compiled into this XEmacs.  Otherwise, it is currently off by
default, but this may change.  NOTE: You *REALLY* should not turn off EOL
detection on Windows!  Your files will have lots of annoying ^M's in them
if you do this."
  (dolist (x '(buffer-file-coding-system-for-read
	       keyboard
	       default-process-coding-system-read
	       no-conversion-coding-system-mapping))
    (set-coding-system-variable
     x (coding-system-change-eol-conversion (get-coding-system-variable x)
					    (if flag nil 'lf)))))

(defun coding-system-current-system-configuration ()
  (cond ((memq system-type '(windows-nt cygwin32))
	 (if (featurep 'mule) 'windows-mule 'windows-no-mule))
	((featurep 'mule) 'unix-mule)
	(eol-detection-enabled-p 'unix-no-mule-eol-detection)
	(t 'unix-no-mule-no-eol-detection)))

(defvar coding-system-variable-default-value-table
  '((buffer-file-coding-system-for-read  binary    raw-text    undecided    raw-text       undecided)
    (default-buffer-file-coding-system   binary    binary      iso-2022-8   raw-text-dos   mswindows-multibyte-dos)
    (file-name                           binary    binary      binary       raw-text-dos   mswindows-multibyte-system-default-dos)
    (native                              binary    binary      binary       raw-text-dos   mswindows-multibyte-system-default-dos)
    (keyboard                            binary    raw-text    undecided    raw-text       undecided)
    ;; the `terminal' coding system is used for output to stderr.  such
    ;; streams do automatic lf->crlf encoding in the C library, so we need
    ;; to not do the same translations ourselves.
    (terminal                            binary    binary      binary       binary         mswindows-multibyte-unix)
    (default-process-coding-system-read  binary    raw-text    undecided    raw-text       undecided)
    (default-process-coding-system-write binary    binary      binary       raw-text   mswindows-multibyte-system-default)
    (no-conversion-coding-system-mapping binary    raw-text    raw-text     raw-text       mswindows-multibyte)
    ))

(defvar coding-system-default-configuration-list
  '(unix-no-mule-no-eol-detection
    unix-no-mule-eol-detection
    unix-mule
    windows-no-mule
    windows-mule))

(defvar coding-system-default-variable-list
  '(buffer-file-coding-system-for-read
    default-buffer-file-coding-system
    file-name
    native
    keyboard
    terminal
    default-process-coding-system-read
    default-process-coding-system-write))

(defun get-coding-system-variable (var)
  "Return the value of a basic coding system variable.
This is intended as a uniform interface onto the coding system settings that
control how encoding detection and conversion works.  See
`coding-system-variable-default-value' for a list of the possible values of
VAR."
  (case var
    (buffer-file-coding-system-for-read buffer-file-coding-system-for-read)
    (default-buffer-file-coding-system
      (default-value 'buffer-file-coding-system))
    (file-name (coding-system-aliasee 'file-name))
    (native (coding-system-aliasee 'native))
    (keyboard (coding-system-aliasee 'keyboard))
    (terminal (coding-system-aliasee 'terminal))
    (default-process-coding-system-read (car default-process-coding-system))
    (default-process-coding-system-write (cdr default-process-coding-system))
    (t (error 'invalid-constant "Invalid coding system variable" var))))

(defun set-coding-system-variable (var value)
  "Set a basic coding system variable to VALUE.
This is intended as a uniform interface onto the coding system settings that
control how encoding detection and conversion works.  See
`coding-system-variable-default-value' for a list of the possible values of
VAR."
  (case var
    (buffer-file-coding-system-for-read
     (set-buffer-file-coding-system-for-read value))
    (default-buffer-file-coding-system
      (set-default-buffer-file-coding-system value))
    (file-name (define-coding-system-alias 'file-name value))
    (native (define-coding-system-alias 'native value))
    (keyboard (set-keyboard-coding-system value))
    (terminal (set-terminal-coding-system value))
    (default-process-coding-system-read
      (setq default-process-coding-system
	    (cons value (cdr default-process-coding-system))))
    (default-process-coding-system-write
      (setq default-process-coding-system
	    (cons (car default-process-coding-system) value)))
    (t (error 'invalid-constant "Invalid coding system variable" var))))

(defun coding-system-variable-default-value (var &optional config)
  "Return the appropriate default value for a coding system variable.

VAR specifies the variable, and CONFIG the configuration, defaulting
to the current system configuration (as returned by
`coding-system-current-system-configuration').

The table of default values looks like this: (see below for abbreviations)


                 Unix      Unix+EOL    Unix+Mule   MSW           MSW+Mule
------------------------------------------------------------------------------
bfcs-for-read    binary    raw-text    undecided   raw-text      undecided
default bfcs     binary    binary      iso-2022-8  raw-text-dos  MSW-MB-dos
file-name        binary    binary      binary      raw-text-dos  MSW-MB-SD-dos
native           binary    binary      binary      raw-text-dos  MSW-MB-SD-dos
keyboard         binary    raw-text    undecided   raw-text      undecided
terminal         binary    binary      binary      binary        MSW-MB-unix
process-read     binary    raw-text    undecided   raw-text      undecided
process-write    binary    binary      binary      raw-text      MSW-MB-SD
no-conv-cs       binary    raw-text    raw-text    raw-text      MSW-MB


VAR can be one of: (abbreviations in parens)

`buffer-file-coding-system-for-read' (bfcs-for-read)

  Lisp variable of the same name; the default coding system used when
  reading in a file, in the absence of more specific settings. (See
  `insert-file-contents' for a description of exactly how a file's
  coding system is determined when it's read in.)

`default-buffer-file-coding-system' (default bfcs)

  Default value of `buffer-file-coding-system', the buffer-local
  variable specifying a file's coding system to be used when it is
  written out.  Set using `set-default-buffer-file-coding-system' (or
  the primitive `setq-default').  When a file is read in,
  `buffer-file-coding-system' for that file is set from the coding
  system used to read the file in; the default value applies to newly
  created files.

`file-name' (file-name)

  The coding system named `file-name'.  Changed using
  `define-coding-system-alias'.  Used internally when passing file
  names to or from system API's, unless the particular API specifies
  another coding system.

`native' (native)

  The coding system named `native'.  Changed using
  `define-coding-system-alias'.  Used internally when passing
  non-file-name text to or from system API's, unless the particular
  API specifies another coding system.

`keyboard' (keyboard)

 #### fill in

`terminal' (terminal)

 #### fill in

`default-process-coding-system-read' (process-read)

 #### fill in

`default-process-coding-system-write' (process-write)

 #### fill in

`no-conversion-coding-system-mapping' (no-conv-cs)

  Coding system used when category `no-conversion' is detected.


CONFIG is one of: (abbreviations in parens)

`unix-no-mule-no-eol-detection' (Unix)

Unix, no Mule support, no automatic EOL detection. (Controlled by
`eol-detection-enabled-p', which is set by the command-line flag
-enable-eol-detection or the configure flag --with-default-eol-detection.)

`unix-no-mule-eol-detection' (Unix+EOL)

Unix, no Mule support, automatic EOL detection.

`unix-mule' (Unix+Mule)

Unix, Mule support.

`windows-no-mule' (MSW)

MS Windows or Cygwin, no Mule support.

`windows-mule'. (MSW+Mule)

MS Windows or Cygwin, Mule support.


The following coding system abbreviations are also used in the table:

MSW-MB = mswindows-multibyte
MSW-MB = mswindows-multibyte-system-default
"
  (setq config (or config (coding-system-current-system-configuration)))
  (let ((defs (cdr (assq var coding-system-variable-default-value-table))))
    (or defs (error 'invalid-constant "Invalid coding system variable" var))
    (let ((pos (position config coding-system-default-configuration-list)))
      (or pos (error 'invalid-constant "Invalid coding system configuration"
		     config))
      (nth pos defs))))

(defun reset-coding-system-defaults (&optional config)
  "Reset all basic coding system variables are set to their default values.
See `coding-system-variable-default-value'."
  (setq config (or config (coding-system-current-system-configuration)))
  (mapcar #'(lambda (var)
	      (set-coding-system-variable
	       var (coding-system-variable-default-value var config)))
	  coding-system-default-variable-list))

(defun reset-coding-categories-to-default ()
"Reset all coding categories (used for automatic detection) to their defaults.

The order of priorities of coding categories and the coding system
bound to each category are as follows:

	coding category		  coding system
	--------------------------------------------------
        utf-16-little-endian-bom  utf-16-little-endian
	utf-16-bom		  utf-16-bom
	iso-7			  iso-2022-7bit
	no-conversion		  raw-text
	utf-8			  utf-8
	iso-8-1			  iso-8859-1
	iso-8-2			  ctext (iso-8859-1 alias)
	iso-8-designate		  ctext (iso-8859-1 alias)
	iso-lock-shift		  iso-2022-lock
	shift-jis		  shift-jis
	big5			  big5
        utf-16-little-endian      utf-16-little-endian
	utf-16			  utf-16
        ucs-4			  ucs-4
"
  ;; #### What a mess!  This needs to be overhauled.

  ;; The old table (from FSF synch?) was not what we use (cf mule-coding.el),
  ;; and as documented iso-8-designate is inconsistent with iso-2022-8bit-ss2.
  ;; The order of priorities of coding categories and the coding system
  ;; bound to each category are as follows:
  ;;
  ;;	coding category		coding system
  ;;	--------------------------------------------------
  ;;	iso-8-2			iso-8859-1
  ;;	iso-8-1			iso-8859-1
  ;;	iso-7			iso-2022-7bit
  ;;	iso-lock-shift		iso-2022-lock
  ;;	iso-8-designate		iso-2022-8bit-ss2
  ;;	no-conversion		raw-text
  ;;	shift-jis		shift_jis
  ;;	big5			big5
  ;;	ucs-4			----
  ;;	utf-8			----
  (when (featurep 'mule)
    (set-coding-category-system 'iso-7	'iso-2022-7)
    (set-coding-category-system 'iso-8-1 'iso-8859-1)
    (set-coding-category-system 'iso-8-2 'ctext)
    (set-coding-category-system 'iso-lock-shift	'iso-2022-lock)
    (set-coding-category-system 'iso-8-designate 'ctext)
    (if (find-coding-system 'shift-jis)
	(set-coding-category-system 'shift-jis 'shift-jis))
    (if (find-coding-system 'big5)
	(set-coding-category-system 'big5 'big5))
    )
  (set-coding-category-system
   'no-conversion
   (coding-system-variable-default-value 'no-conversion-coding-system-mapping))
  (set-coding-category-system 'ucs-4 'ucs-4)
  (set-coding-category-system 'utf-8 'utf-8)
  (set-coding-category-system 'utf-16-little-endian 'utf-16-little-endian)
  (set-coding-category-system 'utf-16 'utf-16)
  (set-coding-category-system 'utf-16-little-endian-bom
			      'utf-16-little-endian-bom)
  (set-coding-category-system 'utf-16-bom 'utf-16-bom)
  (set-coding-priority-list
   (if (featurep 'mule)
       '(utf-16-little-endian-bom
	 utf-16-bom
	 iso-7
	 no-conversion
	 utf-8
	 iso-8-1
	 iso-8-2
	 iso-8-designate
	 iso-lock-shift
	 shift-jis
	 big5
	 utf-16-little-endian
	 utf-16
	 ucs-4)
     '(utf-16-little-endian-bom
       utf-16-bom
       no-conversion
       utf-8
       utf-16-little-endian
       utf-16
       ucs-4))))

(defun reset-language-environment ()
  "Reset coding system environment of XEmacs to the default status.
All basic coding system variables are set to their default values, as
are the coding categories used for automatic detection and their
priority.

BE VERY CERTAIN YOU WANT TO DO THIS BEFORE DOING IT!

For more information, see `reset-coding-system-defaults' and
`reset-coding-categories-to-default'."
  (reset-coding-system-defaults)
  (reset-coding-categories-to-default))

;; Initialize everything so that the remaining Lisp files can contain
;; extended characters.  (They will be in ISO-7 format)

;; !!####!! The Lisp files should all be in UTF-8!!!  That way, all
;; special characters appear as high bits and there's no problem with
;; the Lisp parser trying to read a Mule file and getting all screwed
;; up.  The only other thing then would be characters; we just need to
;; modify the Lisp parser to read the stuff directly after a ? as
;; UTF-8 and return a 30-bit value directly, and modify the character
;; routines a bit to allow such a beast to exist.  MAKE IT A POINT TO
;; IMPLEMENT THIS AS ONE OF MY FUTURE PROJECTS. --ben

(reset-language-environment)

;;; code-init.el ends here