Mercurial > hg > xemacs-beta

view lisp/gtk-faces.el @ 4921:17362f371cc2

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
add more byte-code assertions and better failure output -------------------- ChangeLog entries follow: -------------------- src/ChangeLog addition: 2010-02-03 Ben Wing <ben@xemacs.org> * alloc.c (Fmake_byte_code): * bytecode.h: * lisp.h: * lread.c: * lread.c (readevalloop): * lread.c (Fread): * lread.c (Fread_from_string): * lread.c (read_list_conser): * lread.c (read_list): * lread.c (vars_of_lread): * symbols.c: * symbols.c (Fdefine_function): Turn on the "compiled-function annotation hack". Implement it properly by hooking into Fdefalias(). Note in the docstring to `defalias' that we do this. Remove some old broken code and change code that implemented the old kludgy way of hooking into the Lisp reader into bracketed by `#ifdef COMPILED_FUNCTION_ANNOTATION_HACK_OLD_WAY', which is not enabled. Also enable byte-code metering when DEBUG_XEMACS -- this is a form of profiling for computing histograms of which sequences of two bytecodes are used most often. * bytecode-ops.h: * bytecode-ops.h (OPCODE): New file. Extract out all the opcodes and declare them using OPCODE(), a bit like frame slots and such. This way the file can be included multiple times if necessary to iterate multiple times over the byte opcodes. * bytecode.c: * bytecode.c (NUM_REMEMBERED_BYTE_OPS): * bytecode.c (OPCODE): * bytecode.c (assert_failed_with_remembered_ops): * bytecode.c (READ_UINT_2): * bytecode.c (READ_INT_1): * bytecode.c (READ_INT_2): * bytecode.c (PEEK_INT_1): * bytecode.c (PEEK_INT_2): * bytecode.c (JUMP_RELATIVE): * bytecode.c (JUMP_NEXT): * bytecode.c (PUSH): * bytecode.c (POP_WITH_MULTIPLE_VALUES): * bytecode.c (DISCARD): * bytecode.c (UNUSED): * bytecode.c (optimize_byte_code): * bytecode.c (optimize_compiled_function): * bytecode.c (Fbyte_code): * bytecode.c (vars_of_bytecode): * bytecode.c (init_opcode_table_multi_op): * bytecode.c (reinit_vars_of_bytecode): * emacs.c (main_1): * eval.c (funcall_compiled_function): * symsinit.h: Any time we change either the instruction pointer or the stack pointer, assert that we're going to move it to a valid location. This should catch failures right when they occur rather than sometime later. This requires that we pass in another couple of parameters into some functions (only with error-checking enabled, see below). Also keep track, using a circular queue, of the last 100 byte opcodes seen, and when we hit an assert failure during byte-code execution, output the contents of the queue in a nice readable fashion. This requires that bytecode-ops.h be included a second time so that a table mapping opcodes to the name of their operation can be constructed. This table is constructed in new function reinit_vars_of_bytecode(). Everything in the last two paras happens only when ERROR_CHECK_BYTE_CODE. Add some longish comments describing how the arrays that hold the stack and instructions, and the pointers used to access them, work. * gc.c: Import some code from my `latest-fix' workspace to mark the staticpro's in order from lowest to highest, rather than highest to lowest, so it's easier to debug when something goes wrong. * lisp.h (abort_with_message): Renamed from abort_with_msg(). * symbols.c (defsymbol_massage_name_1): * symbols.c (defsymbol_nodump): * symbols.c (defsymbol): * symbols.c (defkeyword): * symeval.h (DEFVAR_SYMVAL_FWD_OBJECT): Make the various calls to staticpro() instead call staticpro_1(), passing in the name of the C var being staticpro'ed, so that it shows up in staticpro_names. Otherwise staticpro_names just has 1000+ copies of the word `location'.
author Ben Wing <ben@xemacs.org>
date Wed, 03 Feb 2010 08:01:55 -0600
parents 79c6ff3eef26
children 7d06a8bf47d2
line wrap: on
line source

;;; gtk-faces.el --- GTK-specific face frobnication, aka black magic.

;; Copyright (C) 1992-4, 1997 Free Software Foundation, Inc.
;; Copyright (C) 1995, 1996 Ben Wing.
;; Copyright (c) 2000 William Perry

;; Author: William M. Perry <wmperry@gnu.org>
;; Maintainer: XEmacs Development Team
;; Keywords: extensions, internal, dumped

;; This file is part of XEmacs.

;; XEmacs is free software; you can redistribute it and/or modify it
;; under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; XEmacs is distributed in the hope that it will be useful, but
;; WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;; General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with XEmacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Synched up with: Not synched.

;;; Commentary:

;; This file is dumped with XEmacs (when GTK support is compiled in).

(globally-declare-fboundp
 '(gtk-init-pointers
   gtk-font-selection-dialog-new
   gtk-widget-set-sensitive gtk-font-selection-dialog-apply-button
   gtk-signal-connect gtk-main-quit
   gtk-font-selection-dialog-ok-button
   gtk-font-selection-dialog-get-font-name gtk-widget-destroy
   font-menu-set-font font-family font-size
   gtk-font-selection-dialog-cancel-button gtk-widget-show-all
   gtk-main gtk-style-info))

(eval-when-compile
  (defmacro gtk-style-munge-face (face attribute value)
    (let ((func (intern (format "face-%s" (eval attribute)))))
      `(add-spec-to-specifier (,func ,face) ,value nil '(gtk default) 'prepend))))

;;; gtk-init-device-faces is responsible for initializing default
;;; values for faces on a newly created device.
;;;
(defun gtk-init-device-faces (device)
  ;;
  ;; If the "default" face didn't have a font specified, try to pick one.
  ;;
  (when (eq (device-type device) 'gtk)
    (let* ((style (gtk-style-info device))
	   (normal 0)			; GTK_STATE_NORMAL
	   ;;(active 1)			; GTK_STATE_ACTIVE
	   (prelight 2)			; GTK_STATE_PRELIGHT
	   (selected 3)			; GTK_STATE_SELECTED
	   ;;(insensitive 4)		; GTK_STATE_INSENSITIVE
	   )
      (gtk-style-munge-face 'highlight 'foreground
			    (nth prelight (plist-get style 'text)))
      (gtk-style-munge-face 'highlight 'background
			    (nth prelight (plist-get style 'background)))
      (gtk-style-munge-face 'zmacs-region 'foreground
			    (nth selected (plist-get style 'text)))
      (gtk-style-munge-face 'zmacs-region 'background
			    (nth selected (plist-get style 'background)))
      (gtk-style-munge-face 'toolbar 'background
			    (nth normal (plist-get style 'base)))
      (gtk-style-munge-face 'toolbar 'foreground
			    (nth normal (plist-get style 'text)))
      (set-face-background 'modeline [toolbar background] '(gtk default))
      (set-face-foreground 'modeline [toolbar foreground] '(gtk default))
      )
    (gtk-init-pointers)))

;;; This is called from `init-frame-faces', which is called from
;;; init_frame_faces() which is called from Fmake_frame(), to perform
;;; any device-specific initialization.
;;;
(defun gtk-init-frame-faces (frame)
  )

(defun gtk-init-global-faces ()
  )


;;; Lots of this stolen from x-faces.el - I'm not sure if this will
;;; require a rewrite for win32 or not?
(defconst gtk-font-regexp nil)
(defconst gtk-font-regexp-head nil)
(defconst gtk-font-regexp-head-2 nil)
(defconst gtk-font-regexp-weight nil)
(defconst gtk-font-regexp-slant nil)
(defconst gtk-font-regexp-pixel nil)
(defconst gtk-font-regexp-point nil)
(defconst gtk-font-regexp-foundry-and-family nil)
(defconst gtk-font-regexp-registry-and-encoding nil)
(defconst gtk-font-regexp-spacing nil)

;;; Regexps matching font names in "Host Portable Character Representation."
;;;
(let ((- 		"[-?]")
      (foundry		"[^-]*")
      (family 		"[^-]*")
      (weight		"\\(bold\\|demibold\\|medium\\|black\\)")	; 1
;     (weight\?		"\\(\\*\\|bold\\|demibold\\|medium\\|\\)")	; 1
      (weight\?		"\\([^-]*\\)")					; 1
      (slant		"\\([ior]\\)")					; 2
;     (slant\?		"\\([ior?*]?\\)")				; 2
      (slant\?		"\\([^-]?\\)")					; 2
;     (swidth		"\\(\\*\\|normal\\|semicondensed\\|\\)")	; 3
      (swidth		"\\([^-]*\\)")					; 3
;     (adstyle		"\\(\\*\\|sans\\|\\)")				; 4
      (adstyle		"\\([^-]*\\)")					; 4
      (pixelsize	"\\(\\*\\|[0-9]+\\)")				; 5
      (pointsize	"\\(\\*\\|0\\|[0-9][0-9]+\\)")			; 6
;      (resx		"\\(\\*\\|[0-9][0-9]+\\)")			; 7
;      (resy		"\\(\\*\\|[0-9][0-9]+\\)")			; 8
      (resx		"\\([*0]\\|[0-9][0-9]+\\)")			; 7
      (resy		"\\([*0]\\|[0-9][0-9]+\\)")			; 8
      (spacing		"[cmp?*]")
      (avgwidth		"\\(\\*\\|[0-9]+\\)")				; 9
      (registry		"[^-]*") ; some fonts have omitted registries
;      (encoding	".+")		; note that encoding may contain "-"...
      (encoding	"[^-]+")		; false!
      )
  (setq gtk-font-regexp
	(purecopy
	 (concat "\\`\\*?[-?*]"
		 foundry - family - weight\? - slant\? - swidth - adstyle -
		 pixelsize - pointsize - resx - resy - spacing - avgwidth -
		 registry - encoding "\\'"
		 )))
  (setq gtk-font-regexp-head
	(purecopy
          (concat "\\`[-?*]" foundry - family - weight\? - slant\?
		  "\\([-*?]\\|\\'\\)")))
  (setq gtk-font-regexp-head-2
	(purecopy
          (concat "\\`[-?*]" foundry - family - weight\? - slant\?
		  - swidth - adstyle - pixelsize - pointsize
		  "\\([-*?]\\|\\'\\)")))
  (setq gtk-font-regexp-slant (purecopy (concat - slant -)))
  (setq gtk-font-regexp-weight (purecopy (concat - weight -)))
  ;; if we can't match any of the more specific regexps (unfortunate) then
  ;; look for digits; assume 2+ digits is 10ths of points, and 1-2 digits
  ;; is pixels.  Bogus as hell.
  (setq gtk-font-regexp-pixel (purecopy "[-?*]\\([0-9][0-9]?\\)[-?*]"))
  (setq gtk-font-regexp-point (purecopy "[-?*]\\([0-9][0-9]+\\)[-?*]"))
  ;; the following two are used by x-font-menu.el.
  (setq gtk-font-regexp-foundry-and-family
	(purecopy (concat "\\`[-?*]" foundry - "\\(" family "\\)" -)))
  (setq gtk-font-regexp-registry-and-encoding
	(purecopy (concat - "\\(" registry "\\)" - "\\(" encoding "\\)\\'")))
  (setq gtk-font-regexp-spacing
	(purecopy (concat - "\\(" spacing "\\)" - avgwidth
			  - registry - encoding "\\'")))
  )

(defvaralias 'x-font-regexp 'gtk-font-regexp)
(defvaralias 'x-font-regexp-head 'gtk-font-regexp-head)
(defvaralias 'x-font-regexp-head-2 'gtk-font-regexp-head-2)
(defvaralias 'x-font-regexp-weight 'gtk-font-regexp-weight)
(defvaralias 'x-font-regexp-slant 'gtk-font-regexp-slant)
(defvaralias 'x-font-regexp-pixel 'gtk-font-regexp-pixel)
(defvaralias 'x-font-regexp-point 'gtk-font-regexp-point)
(defvaralias 'x-font-regexp-foundry-and-family 'gtk-font-regexp-foundry-and-family)
(defvaralias 'x-font-regexp-registry-and-encoding 'gtk-font-regexp-registry-and-encoding)
(defvaralias 'x-font-regexp-spacing 'gtk-font-regexp-spacing)

(defun gtk-frob-font-weight (font which)
  (if (font-instance-p font) (setq font (font-instance-name font)))
  (cond ((null font) nil)
	((or (string-match gtk-font-regexp font)
	     (string-match gtk-font-regexp-head font)
	     (string-match gtk-font-regexp-weight font))
	 (concat (substring font 0 (match-beginning 1)) which
		 (substring font (match-end 1))))
	(t nil)))

(defun gtk-frob-font-slant (font which)
  (if (font-instance-p font) (setq font (font-instance-name font)))
  (cond ((null font) nil)
	((or (string-match gtk-font-regexp font)
	     (string-match gtk-font-regexp-head font))
	 (concat (substring font 0 (match-beginning 2)) which
		 (substring font (match-end 2))))
	((string-match gtk-font-regexp-slant font)
	 (concat (substring font 0 (match-beginning 1)) which
		 (substring font (match-end 1))))
	(t nil)))

(defun gtk-make-font-bold (font &optional device)
  (or (try-font-name (gtk-frob-font-weight font "bold") device)
      (try-font-name (gtk-frob-font-weight font "black") device)
      (try-font-name (gtk-frob-font-weight font "demibold") device)))

(defun gtk-make-font-unbold (font &optional device)
  (try-font-name (gtk-frob-font-weight font "medium") device))

(defcustom try-oblique-before-italic-fonts t
  "*If nil, italic fonts are searched before oblique fonts.
If non-nil, oblique fonts are tried before italic fonts.  This is mostly
applicable to adobe-courier fonts"
  :type 'boolean
  :tag "Try Oblique Before Italic Fonts"
  :group 'x)
(define-obsolete-variable-alias '*try-oblique-before-italic-fonts*
  'try-oblique-before-italic-fonts)

(defun gtk-make-font-italic (font &optional device)
  (if try-oblique-before-italic-fonts
      (or (try-font-name (gtk-frob-font-slant font "o") device)
	  (try-font-name (gtk-frob-font-slant font "i") device))
    (or (try-font-name (gtk-frob-font-slant font "i") device)
	(try-font-name (gtk-frob-font-slant font "o") device))))

(defun gtk-make-font-unitalic (font &optional device)
  (try-font-name (gtk-frob-font-slant font "r") device))

(defun gtk-make-font-bold-italic (font &optional device)
  (if try-oblique-before-italic-fonts
      (or (try-font-name
	   (gtk-frob-font-slant (gtk-frob-font-weight font "bold") "o") device)
	  (try-font-name
	   (gtk-frob-font-slant (gtk-frob-font-weight font "bold") "i") device)
	  (try-font-name
	   (gtk-frob-font-slant (gtk-frob-font-weight font "black") "o") device)
	  (try-font-name
	   (gtk-frob-font-slant (gtk-frob-font-weight font "black") "i") device)
	  (try-font-name
	   (gtk-frob-font-slant (gtk-frob-font-weight font "demibold") "o") device)
	  (try-font-name
	   (gtk-frob-font-slant (gtk-frob-font-weight font "demibold") "i") device))
    (or (try-font-name
	 (gtk-frob-font-slant (gtk-frob-font-weight font "bold") "i") device)
	(try-font-name
	 (gtk-frob-font-slant (gtk-frob-font-weight font "bold") "o") device)
	(try-font-name
	 (gtk-frob-font-slant (gtk-frob-font-weight font "black") "i") device)
	(try-font-name
	 (gtk-frob-font-slant (gtk-frob-font-weight font "black") "o") device)
	(try-font-name
	 (gtk-frob-font-slant (gtk-frob-font-weight font "demibold") "i") device)
	(try-font-name
	 (gtk-frob-font-slant (gtk-frob-font-weight font "demibold") "o") device))))

(defun gtk-choose-font ()
  (interactive)
  (require 'x-font-menu)
  (require 'font)
  (let ((locale (if font-menu-this-frame-only-p
		    (selected-frame)
		  nil))
	(dialog nil))
    (setq dialog (gtk-font-selection-dialog-new "Choose default font..."))
    (put dialog 'modal t)
    (put dialog 'type 'dialog)

    (gtk-widget-set-sensitive (gtk-font-selection-dialog-apply-button dialog) nil)
    (gtk-signal-connect dialog 'destroy (lambda (&rest ignored) (gtk-main-quit)))
    (gtk-signal-connect (gtk-font-selection-dialog-ok-button dialog)
			'clicked
			(lambda (button data)
			  (let* ((dialog (car data))
				 (font (font-create-object
					(gtk-font-selection-dialog-get-font-name dialog))))
			    (gtk-widget-destroy dialog)
			    (font-menu-set-font (car (font-family font)) nil (* 10 (font-size font)))))
			(cons dialog locale))
    (gtk-signal-connect (gtk-font-selection-dialog-cancel-button dialog)
			'clicked
			(lambda (button dialog)
			  (gtk-widget-destroy dialog)) dialog)

    (gtk-widget-show-all dialog)
    (gtk-main)))