[xemacs-hg @ 2002-08-28 05:36:20 by youngs] 2002-08-16 Steve Youngs <youngs@xemacs.org> * version.sh (xemacs_extra_name): New var to identify XEmacs version > release < next release. ie, release+cvs. * configure.in: Test for xemacs_extra_name. * configure: Re-generate. 2002-08-16 Steve Youngs <youngs@xemacs.org> * build-report.el (build-report-installation-version-regexp): Update to cater for 'xemacs-extra-name'. (build-report-version-file-regexp): Ditto. (build-report): Ditto. (build-report-installation-data): Ditto. (build-report-version-file-data): Ditto. * version.el (emacs-version): Test for 'xemacs-extra-name'. 2002-08-16 Steve Youngs <youngs@xemacs.org> * config.h.in (XEMACS_EXTRA_NAME): New. * emacs.c (vars_of_emacs): Use it.

#!/bin/sh
#
#	ad2c : Convert app-defaults file to C strings decls.
#
#	George Ferguson, ferguson@cs.rcohester.edu, 12 Nov 1990.
#	19 Mar 1991 : gf
#		Made it self-contained.
#	6 Jan 1992 : mycroft@gnu.ai.mit.edu (Charles Hannum)
#		Removed use of "-n" and ":read" label since Gnu and
#		IBM sed print pattern space on "n" command. Still works
#		with Sun sed, of course.
#	7 Jan 1992: matthew@sunpix.East.Sun.COM (Matthew Stier)
#		Escape quotes after escaping backslashes.
#
# Synched up with: Not in FSF.

sed '
/^!/d
/^$/d
s/\\/\\\\/g
s/\\$//g
s/"/\\"/g
s/^/"/
: test
/\\$/b slash
s/$/",/
p
d
: slash
n
/^!/d
/^$/d
s/"/\\"/g
s/\\\\/\\/g
s/\\n/\\\\n/g
s/\\t/\\\\t/g
s/\\f/\\\\f/g
s/\\b/\\\\b/g
b test' "$@"