Mercurial > hg > ooxml

<?xml version='1.0'?>
<!DOCTYPE doc SYSTEM "../../../lib/xml/xsl.dtd" >
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="3.0" xmlns:s="http://schemas.openxmlformats.org/spreadsheetml/2006/main" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:e="http://markup.co.uk/excel" exclude-result-prefixes="xs s xpf e" xmlns="http://www.w3.org/1999/xhtml" xmlns:xpf="http://www.w3.org/2005/xpath-functions">
 <xsl:strip-space elements="e:a"/>
 <xsl:output omit-xml-declaration="yes"/>

 <xsl:include href="n2a.xsl"/>

 <xsl:template match="/">
  <html>
   <head>
    <meta http-equiv="Content-type" content="text/html; charset=utf-8"/>
    <style>
       body {font-family: 'DejaVu Sans Mono' , monospace}
       td {padding: 0}
       .e {color: red}
       .formula {font-style: italic}
       .reffed {border: solid 1px black}
       table {table-layout: fixed}
       th {width: 1en}
      /* http://stackoverflow.com/questions/470690/how-to-automatically-generate-n-distinct-colors */
      .c1 {background-color: #FFB300} /* Vivid Yellow */
      .c2 {background-color: #803E75} /* Strong Purple */
      .c3 {background-color: #FF6800} /* Vivid Orange */
      .c4 {background-color: #A6BDD7} /* Very Light Blue */
      .c5 {background-color: #C10020} /* Vivid Red */
      .c6 {background-color: #CEA262} /* Grayish Yellow */
      .c7 {background-color: #817066} /* Medium Gray */
      /* The following don't work well for people with defective color vision */
      .c8 {background-color: #007D34} /* Vivid Green */
      .c9 {background-color: #F6768E} /* Strong Purplish Pink */
      .c10 {background-color: #00538A} /* Strong Blue */
      .c11 {background-color: #FF7A5C} /* Strong Yellowish Pink */
      .c12 {background-color: #53377A} /* Strong Violet */
      .c13 {background-color: #FF8E00} /* Vivid Orange Yellow */
      .c14 {background-color: #B32851} /* Strong Purplish Red */
      .c15 {background-color: #F4C800} /* Vivid Greenish Yellow */
      .c16 {background-color: #7F180D} /* Strong Reddish Brown */
      .c17 {background-color: #93AA00} /* Vivid Yellowish Green */
      .c18 {background-color: #593315} /* Deep Yellowish Brown */
      .c19 {background-color: #F13A13} /* Vivid Reddish Orange */
      .c20 {background-color: #232C16} /* Dark Olive Green */
    </style>
   </head>
   <body>
    <xsl:apply-templates/>
   </body>
  </html>
 </xsl:template>

 <xsl:template match="e:a">
  <xsl:variable name="n" select="count(e:r[1]/e:c)"/>
  <table>
   <thead>
   <tr>
    <xsl:for-each select="1 to $n">
     <th/>
    </xsl:for-each>
   </tr>
   </thead>
   <tbody><xsl:apply-templates/></tbody>
  </table>
 </xsl:template>

 <xsl:template match="e:r">
  <tr><xsl:apply-templates/></tr>
  <xsl:text>&#10;</xsl:text>
 </xsl:template>

 <xsl:template match="e:c">
  <td>
   <xsl:choose>
    <xsl:when test="@t|text()">
     <xsl:attribute name="class">
      <xsl:value-of select="(if (@t) then @t else text(),
                             if (e:f) then 'formula' else (),
                             if (e:i) then 'reffed' else (),
                             if (@fi) then concat('c',@fi) else ())"/>
     </xsl:attribute>
     <xsl:attribute name="title">
      <xsl:choose>
       <xsl:when test="e:i">
        <xsl:value-of select="e:i/@r"/>: <xsl:value-of select="e:i/e:r"/>
       </xsl:when>
       <xsl:otherwise>
        <xsl:value-of select="e:n2a(@c)"/><xsl:value-of select="../@r"/>
       </xsl:otherwise>
      </xsl:choose>
     </xsl:attribute>
     <xsl:value-of select="if (@t) then @t else text()"/></xsl:when>
    <xsl:otherwise></xsl:otherwise>
   </xsl:choose>
   </td>
 </xsl:template>
</xsl:stylesheet>
author	Henry S. Thompson <ht@markup.co.uk>
date	Thu, 11 May 2017 09:29:33 +0100
parents	5b2333e59d91
children	f90bbd38b8f6